Bootstrapping a “degenerate” VOA

Chiral Algebras for the 21st Century
UC Davis Spring School
April 2019

Load K. Thielemans’ OPEdefs package

Quit[]

SetDirectory[NotebookDirectory[]];
<<OPEdefs`
Prettify[expression_]:=DeleteDuplicates[DeleteCases[Flatten[Simplify[expression]],0]]

Initialize operators: Stress tensor and (Subscript[V, k])((Subscript[sl, 2])) currents

Bosonic[T,h,e,f];

Operator lists

OPS[Δ][z] lists operators with conformal dimension Δ and U(1) charge z

OPS[0][0]={One};

OPS[1][1]={e};
OPS[1][0]={h};
OPS[1][-1]={f};

OPS[2][2]={NO[e,e]};
OPS[2][1]={e',NO[h,e]};
OPS[2][0]={NO[e,f],NO[h,h],h',T};
OPS[2][-1]={f',NO[h,f]};
OPS[2][-2]={NO[f,f]};

Virasoro OPE

OPE[T,T]:=MakeOPE[(((cc/2)One)/(((z-w))^4))+((2 T)/(((z-w))^2))+((T')/(z-w))+Ord[z,w,0]]
OPE[T,e]:=MakeOPE[(e/(((z-w))^2))+((e')/(z-w))+Ord[z,w,0]]
OPE[T,h]:=MakeOPE[(h/(((z-w))^2))+((h')/(z-w))+Ord[z,w,0]]
OPE[T,f]:=MakeOPE[(f/(((z-w))^2))+((f')/(z-w))+Ord[z,w,0]]

Heisenberg OPE

OPE[h,e]:=MakeOPE[((e )/((z-w)))+Ord[z,w,0]]
OPE[h,f]:=MakeOPE[((-f)/((z-w)))+Ord[z,w,0]]
OPE[h,h]:=MakeOPE[(((1/2) k )/(((z-w))^2))+Ord[z,w,0]]

Other OPE

OPE[e,f]:=MakeOPE[((k One)/(((z-w))^2))+((2h)/(z-w))+Ord[z,w,0]]
OPE[e,e]:=MakeOPE[Ord[z,w,0]]
OPE[f,f]:=MakeOPE[Ord[z,w,0]]

Verify Jacobi identities

Prettify[

OPEJacobi[#[[1]],#[[2]],#[[3]]]&/@Tuples[{e,f,h,T},3]

]

Find degenerate central charge

Det[

Table[OPEPole[2][OPS[1][0][[i]],OPS[1][0][[j]]],{i,1,Length[OPS[1][0]]},{j,1,Length[OPS[1][0]]}]

]

Det[

Table[OPEPole[2][OPS[1][1][[i]],OPS[1][-1][[j]]],{i,1,Length[OPS[1][1]]},{j,1,Length[OPS[1][-1]]}]

]

Det[

Table[OPEPole[4][OPS[2][0][[i]],OPS[2][0][[j]]],{i,1,Length[OPS[2][0]]},{j,1,Length[OPS[2][0]]}]

]

Simplify[Solve[%==0,cc]]

Find null space

NullSpace[

Table[OPEPole[4][OPS[2][0][[i]],OPS[2][0][[j]]],{i,1,Length[OPS[2][0]]},{j,1,Length[OPS[2][0]]}]/.{cc->((3k)/(2+k))}

]

NullSpace[Table[OPEPole[4][OPS[2][0][[i]],OPS[2][0][[j]]],{i,1,Length[OPS[2][0]]},{j,1,Length[OPS[2][0]]}]/.{cc->((3k)/(2+k))}].OPS[2][0]